# Maintainer: Collabora Ltd <gael.portay@collabora.com>

pkgname=steamos-efi-git
pkgver=r260.cef6114
pkgrel=1
pkgdesc='Stage 1 bootloader for SteamOS 3+'
arch=('x86_64')
url='http://repo.steampowered.com'
license=('GPL2')
makedepends=('git' 'gnu-efi-libs')
optdepends=('efibootmgr: For steamcl-install EFI support')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
install="${pkgname%-git}.install"
source=("${pkgname%-git}::git+https://gitlab.steamos.cloud/steam/${pkgname%-git}.git"
        "0007-Fix-ambigous-no-pie-in-LDFLAGS.patch")

md5sums=('SKIP'
         'c6c68f79688953e3f4b44c93f2898915')

pkgver() {
	cd "${pkgname%-git}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
	cd "${pkgname%-git}"
	patch -p1 -i "${srcdir}/0007-Fix-ambigous-no-pie-in-LDFLAGS.patch"
}

build() {
	cd "${pkgname%-git}"
	autoreconf -vif
	./configure --prefix=/usr --with-release-version="$pkgver"
	make
}

package() {
	cd "${pkgname%-git}"
	make DESTDIR="$pkgdir/" install
	mv "$pkgdir/usr/sbin/"* "$pkgdir/usr/bin/"
	rmdir "$pkgdir/usr/sbin/"
}
