# Maintainer: Collabora Ltd <gael.portay@collabora.com>

pkgbase=steamos-customizations-git
pkgname=('steamos-pipewire-settings' 'steamos-customizations-git' 'holo-sudo')
pkgver=r605.e579d84
pkgrel=1
pkgdesc='SteamOS customizations - This package installs various SteamOS-specific files'
arch=('any')
url='http://repo.steampowered.com'
license=('LGPLv2+')
depends=('e2fsprogs' 'gptfdisk' 'rsync' 'util-linux')
makedepends=('git')
source=("${pkgbase%-git}::git+https://gitlab.steamos.cloud/steam/${pkgbase%-git}.git")
md5sums=('SKIP')

pkgver() {
	cd "${pkgbase%-git}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package_steamos-customizations-git() {
	provides=("${pkgbase%-git}")
	conflicts=("${pkgbase%-git}")

	cd "${pkgbase%-git}"
	make DESTDIR="$pkgdir" prefix="/usr" sbindir="/usr/bin" libexecdir="/usr/lib" install

	echo "Symlink grub binaries using steamos helpers from libdir..."
	ln -sf "/usr/lib/steamos/steamos-grub-install" "${pkgdir}/usr/bin/grub-install"
	ln -sf "/usr/lib/steamos/steamos-grub-mkimage" "${pkgdir}/usr/bin/grub-mkimage"

	# The pipewire settings live in separate package
	rm -rf "${pkgdir}/etc/pipewire"
	# The sudo settings live in separate package
	rm -rf "${pkgdir}/etc/sudoers.d"
}

package_steamos-pipewire-settings() {
	pkgdesc='SteamOS customizations - pipewire settings'
	depends=('pipewire-media-session=1:0.4.1-1') # NOTE: update the config on each pipewire-media-session change

	cd "${pkgbase%-git}"
	make -C pipewire DESTDIR="$pkgdir" prefix="/usr" sbindir="/usr/bin" libexecdir="/usr/lib" install
}

package_holo-sudo() {
	pkgdesc='Holo customizations - sudo settings'
	depends=()
	group=(holo-base)

	cd "${pkgbase%-git}"
	make DESTDIR="$pkgdir" prefix="/usr" sbindir="/usr/bin" libexecdir="/usr/lib" install-sudo
}
