# Maintainer: Gaël PORTAY <gael.portay@collabora.com>

pkgname=('python-steamos-atomupd-git' 'steamos-atomupd-client-git' 'steamos-atomupd-server-git')
pkgbase=steamos-atomupd-git
pkgver=r149.634106e
pkgrel=2
arch=('any')
url='https://store.steampowered.com/steamos/'
license=('LGPL2.1')
makedepends=('git' 'python3')
source=("${pkgbase%-git}::git+https://gitlab.steamos.cloud/steam/${pkgbase%-git}.git")
md5sums=('SKIP')

pkgver() {
	cd "${pkgbase%-git}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "${pkgbase%-git}"
	python setup.py build
}

package_python-steamos-atomupd-git() {
	pkgdesc='SteamOS Atomic Update - Python library that is used by both the client and the server.'
	depends=('python3' 'python-semantic-version')
	provides=("${pkgname%-git}")
	conflicts=("${pkgname%-git}")

	cd "${pkgbase%-git}"
	python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
}

package_steamos-atomupd-client-git() {
	pkgdesc='SteamOS Atomic Update (client) - Atomic update client for SteamOS.'
	depends=('python3' 'rauc' "python-${pkgbase%-git}")
	optdepends=('casync')
	provides=("${pkgname%-git}")
	conflicts=("${pkgname%-git}")

	cd "${pkgbase%-git}"
	install -Dm755 "bin/steamos-atomupd-client" "$pkgdir/usr/bin/steamos-atomupd-client"
	install -Dm755 "bin/steamos-atomupd-mkmanifest" "$pkgdir/usr/bin/steamos-atomupd-mkmanifest"
	install -Dm644 "completions/steamos-atomupd-client" "$pkgdir/usr/share/bash-completion/completions/steamos-atomupd-client"
	install -Dm644 "completions/steamos-atomupd-mkmanifest" "$pkgdir/usr/share/bash-completion/completions/steamos-atomupd-mkmanifest"
	install -dm755 "$pkgdir/usr/lib/steamos-atomupd"
	install -dm755 "$pkgdir/etc/steamos-atomupd"
	install -Dm644 "examples/client.conf" "$pkgdir/usr/share/steamos-atomupd-client/examples/client.conf"
	install -Dm644 "examples/image.manifest.json" "$pkgdir/usr/share/steamos-atomupd-client/examples/image.manifest.json"
}

package_steamos-atomupd-server-git() {
	pkgdesc='SteamOS Atomic Update (server) - Atomic update server for SteamOS.'
	depends=('python3' 'python-flask' "python-${pkgbase%-git}")
	provides=("${pkgname%-git}")
	conflicts=("${pkgname%-git}")

	cd "${pkgbase%-git}"
	install -Dm755 "bin/steamos-atomupd-server" "$pkgdir/usr/bin/steamos-atomupd-server"
	install -Dm644 "completions/steamos-atomupd-server" "$pkgdir/usr/share/bash-completion/completions/steamos-atomupd-server"
	install -Dm644 "data/steamos-atomupd-server@.service.in" "$pkgdir/usr/lib/systemd/system/steamos-atomupd-server@.service"
	sed -e 's,@bindir@,/usr/bin,g' -i "$pkgdir/usr/lib/systemd/system/steamos-atomupd-server@.service"
	install -Dm644 "examples/server-snapshots.conf" "$pkgdir/usr/share/steamos-atomupd-server/examples/server-snapshots.conf"
	install -Dm644 "examples/server-releases.conf" "$pkgdir/usr/share/steamos-atomupd-server/examples/server-releases.conf"
	install -Dm644 "examples/update.json" "$pkgdir/usr/share/steamos-atomupd-server/examples/update.json"
	install -Dm755 "examples/build-image-hierarchy.sh" "$pkgdir/usr/share/steamos-atomupd-server/examples/build-image-hierarchy.sh"
}
